首页 > 代码 > 常规代码 > 正文

代码

阅读排行

文件夹内循环读取文件[仅适用于VF编译器]
2014-01-20 17:50:31   来源:Fcode研讨团队   评论:0 点击:

本例可用于在同一个文件夹下,对文件名符合一定要求的文件进行循环。使用了VF(IVF,CVF,DVF)所扩展的函数,请确认您的编译器允许。

本例代码如下,将所有 C 盘下的文件输出,如果你懂得 windows通配符,那么使用这个代码会更得心应手,否则,您可能需要先了解一下它,效果如图:

\


Program www_fcode_cn
   Implicit None
   integer :: n
   External ToDoOneFile
   call DoWithWildcard( "C:\*.*" , ToDoOneFile , n )
   write(*,*) '共',n,'个文件'
End Program www_fcode_cn

Subroutine ToDoOneFile( cFile , iLoop )
   Character( Len = * ) , Intent( IN ) :: cFile
   Integer , Intent( IN ) :: iLoop
   Write( * , * ) '第',iLoop,'个文件:',cFile
   !Open( 12 , File = cFile )
   !Read( 12 )
   !Close( 12 )
End Subroutine ToDoOneFile

   
Subroutine DoWithWildcard(cWildcard,CallBack,iTotal)
   !// 下一句代码,如果是 Compaq 或 Digital,需改为 Use DFLib
   Use IFPort , only : GetFileInfoQQ , GetLastErrorQQ , FILE$INFO , FILE$LAST , FILE$ERROR , FILE$FIRST , ERR$NOMEM , ERR$NOENT , FILE$DIR
   Implicit None
   Interface 
     Subroutine CallBack( cFile , iLoop )
       Character( Len = * ) , Intent( IN ) :: cFile
       Integer , Intent( IN ) :: iLoop
     End Subroutine CallBack
   End Interface
   Character( Len = * ) , Intent( IN ) :: cWildcard
   Integer , Intent( OUT ) :: iTotal
   Type (FILE$INFO) :: stInfo
   Integer(4) :: iWildhandle , iLength , iRet
   iWildhandle = FILE$FIRST
   iTotal = 0
   Do While (.TRUE.)
       iLength = GetFileInfoQQ( cWildCard , stInfo , iWildhandle )
       If (( iWildhandle == FILE$LAST) .OR.( iWildhandle == FILE$ERROR )) then
         Select Case (GetLastErrorQQ())
         Case (ERR$NOMEM)  !//内存不足
           iTotal = - 1
           return
         Case (ERR$NOENT)  !//碰到通配符序列尾
           return
         Case Default
           iTotal = 0
           return
         End Select
       End If
       If ( ( stInfo%permit.AND.FILE$DIR ) == 0 ) then
         call CallBack( Trim(stInfo%Name) , iTotal + 1 )
         iTotal = iTotal + 1
       End If
   End Do
 End Subroutine DoWithWildcard

相关热词搜索:文件夹 循环 读取文件

上一篇:为整数添加千分位符号函数
下一篇:MD5 哈希值计算程序

分享到: 收藏